易语言信息框加入按钮倒计时关闭模块源码

.子程序 处理线程
.参数 参_存留时间, 整数型
.局部变量 局_测试句柄, 整数型
.局部变量 局_目标句柄, 整数型
.局部变量 局_计次, 整数型
.局部变量 局_默认标题, 文本型
.局部变量 局_显示句柄, 整数型

.如果真 (参_存留时间 ≤ 0)
返回 ()
.如果真结束
' 实际在寻找句柄的时候，最好能继续验证子窗口的句柄以便确认窗口没有“找错”。
' 局_测试句柄 ＝ API_寻找顶级窗口 (“#32770”, 集_消息标题)
.判断循环首 (局_测试句柄 ＝ 0)
局_测试句柄 ＝ API_寻找顶级窗口 (“#32770”, 集_消息标题)
处理事件 ()
.判断循环尾 ()
.计次循环首 (集_按钮索引, 局_计次)
局_目标句柄 ＝ API_寻找子窗口 (局_测试句柄, 局_目标句柄, “Button”, 字符 (0))
.计次循环尾 ()
.如果真 (集_显示位置 ≠ 0)
.判断循环首 (局_目标句柄 ＝ 0)
局_测试句柄 ＝ API_寻找顶级窗口 (“#32770”, 集_消息标题)
.计次循环首 (集_按钮索引, 局_计次)
局_目标句柄 ＝ API_寻找子窗口 (局_测试句柄, 局_目标句柄, “Button”, 字符 (0))
.计次循环尾 ()
.判断循环尾 ()
.如果真结束

.判断开始 (集_显示位置 ＝ 0)
局_显示句柄 ＝ 局_测试句柄
.判断 (集_显示位置 ＝ 2)
局_显示句柄 ＝ 局_目标句柄
.判断 (集_显示位置 ＝ 1)
.判断循环首 (局_显示句柄 ＝ 0)
局_显示句柄 ＝ API_寻找子窗口 (局_测试句柄, 0, “Static”, 字符 (0))
.判断循环尾 ()
.默认
局_显示句柄 ＝ 局_目标句柄
.判断结束
局_默认标题 ＝ _取窗口标题 (局_显示句柄)
.变量循环首 (参_存留时间, 0, -1, 局_计次)
.如果 (局_显示句柄 ＝ 局_目标句柄)
API_设置窗口标题 (局_显示句柄, 局_默认标题 ＋ “(” ＋ 到文本 (局_计次) ＋ “)”)
.否则
API_设置窗口标题 (局_显示句柄, 局_默认标题 ＋ “(剩余:” ＋ 到文本 (局_计次) ＋ “秒)”)
.如果结束
延时 (1000)
.变量循环尾 ()

.如果真 (集_修改信息框内容 ≠ “”)
.判断开始 (集_倒计时修改内容位置 ＝ 0)
API_设置窗口标题 (局_测试句柄, 集_修改信息框内容)
.判断 (集_倒计时修改内容位置 ＝ 1)
API_设置窗口标题 (API_寻找子窗口 (局_测试句柄, 0, “Static”, 字符 (0)), 集_修改信息框内容)
.判断 (集_倒计时修改内容位置 ＝ 2)
API_设置窗口标题 (局_显示句柄, 集_修改信息框内容)
.默认

.判断结束

.如果真结束

' 为了避免其他干扰而没有单击按钮
.如果真 (集_是否自动按钮 ＝ 1)
.判断循环首 (API_判断窗口句柄 (局_目标句柄) ≠ 0)
API_发送消息 (局_目标句柄, 513, 0, 0)
API_发送消息 (局_目标句柄, 514, 0, 0)
.判断循环尾 ()